Tips zum Programm

Gnuplot ist eine freie Software welche einfach per ‚apt update && apt install gnuplot‘ installiert wird.
Ein wesentlicher Vorteil ist das es komplett über Scripte gesteuert werden kann.
Dadurch lassen sich die Abläufe um z.B regelmäßig eine neue Grafik zu erhalten mit einem zusätzlichen Cronjob komplett automatisieren.
Beispiel um die Grafik auf der Klima Seite alle 30 Minuten neu Plotten zu lassen:

Crontab -e
# Klima Bilder für Webserver Plotten.
3 * * * * /etc/ntp/scripte/plot-sht85.sh > /dev/null
33 * * * * /etc/ntp/scripte/plot-sht85.sh > /dev/null

Script Inhalt von plot-sht85.sh:

#! /usr/bin/gnuplot
#
set terminal png enhanced size 1200,400 background '#FAF7EB'
set output "/tmp/up/sht85.png"
data = '/tmp/sht85.log'        # Quasi ein #define.
set grid
set grid xtics mxtics ytics mytics
set ytics nomirror
set ytics 0.500                # Auflösung links für Temperatur runterdrehen.
set y2tics 0.500               # Und Rechts fuer die RH%.
set decimalsign ','            # Komma anstatt Punkt anzeigen.
set format y "%.1f"            # 1 Nachkommastelle, Nullen auffüllen auf'°C' Werte.
set format y2 "%.1f"           # 1 Nachkommastelle, Nullen auffüllen auf 'RH %' Werte.
#
set xrange [00 : 86400]        # Nach Mitternacht wenn X Achse noch leer, direkt auf 24 Stunden anzeigen.
set xtics 3600                 # Jede volle Stunde beschriften und jede halbe Stunde ein Skalenstrich.
set xtics rotate by 45 right   # Stundenaneige kippen.
set autoscale ymin
set autoscale ymax
#
set format x "%H"              # Ausgabeformat, nur die Stunden auf der X Achse.
set xdata time                 # Einleseformat
set timefmt "%H:%M:%S"         # Einleseformat, anpassen je nachdem wie man die Zeitangabe loggt.
#
set ylabel textcolor rgb '#a2142f' "Gehäuse Temperatur in °C" font "Linux Libertine 0:style=Bold,11"
set y2label textcolor rgb '#0072bd' "Relative Luftfeuchte in %" font "Linux Libertine 0:style=Bold,11"
set xlabel "Lokale Zeit (MESZ/CEST | MEZ/CET)" font "LiberationSerif-Italic,10"
set mytics                     # Horizontale Skalenstriche (Raster) links.
#
plot data using 2:4 notitle with line lc rgb "red" axes x1y1, \
         data using 2:7 notitle with line lc rgb "blue" axes x1y2